home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 14 / CU Amiga Magazine's Super CD-ROM 14 (1997)(EMAP Images)(GB)(Track 1 of 3)[!][issue 1997-09].iso / InitCD < prev    next >
AmigaDOS Script File  |  1997-07-21  |  4KB  |  145 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14.  
  15. Assign CUCD: :
  16.  
  17. If {arg} EQ "CHECK"         ; Exit if InitCD has been run, otherwise ask
  18.     If $CDInit EQ TRUE
  19.         Skip END
  20.     Else
  21.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  22.         If $init EQ 0
  23.             Skip END
  24.         EndIf
  25.     EndIf
  26. EndIf
  27.  
  28. ;if $CDBoot EQ TRUE
  29. ;    C:NoReset
  30. ;    endif
  31.  
  32. If $CDInit EQ TRUE
  33.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  34.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  35.         Quit
  36.     EndIf
  37.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  38.     If $remass EQ 1
  39.         execute UnInitCD
  40.     EndIf
  41.     Quit
  42. EndIf
  43.  
  44. ; Set these assigns and paths only if not booting from CD
  45. IF $CDBoot NOT EQ TRUE
  46.     Run >NIL: RequestChoice "InitCD" "Setting up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on the Workbench." " OK "
  47.     Assign Fonts:   CUCD:Fonts ADD
  48.     Assign Libs:    CUCD:Libs ADD
  49.     Assign L:       CUCD:L ADD
  50.     Assign S:       CUCD:S ADD
  51.     Assign LIBS:    CUCD:Classes ADD
  52.     Path CUCD:C CUCD:System CUCD:System/CDsupport CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  53.  
  54.     ; Make environment variables defined on CD available to system
  55.     Failat 21
  56.     Assign >NIL: ENV: CUCD14:Prefs/Env-Archive ADD
  57.     ; For HappyENV users
  58.     If FAIL     
  59.         Assign >NIL: ENVARC: CUCD14:Prefs/Env-Archive ADD  
  60.     EndIf
  61. EndIF
  62.  
  63. ; Set some system assigns
  64. Assign WWW:             CUCD:CUCD/WWW
  65. Assign GM:              CUCD:System/CDsupport/GMPlay ADD
  66. Assign CUCDNews:        CUCD:CUCD/Online/News
  67. Assign Twist:           CUCD:CUCD/Magazine/Issues
  68. Assign TwistIcon:       Twist:Icons
  69.  
  70. ; Add paths
  71. Path GM: ADD
  72.  
  73. ; Add MUI if no MUI installed.
  74. Assign MUI: EXISTS >NIL:
  75. IF WARN
  76.     Assign MUI:    CUCD:System/MUI
  77.     Assign Libs:   MUI:Libs ADD
  78.     Assign LOCALE: MUI:Locale ADD
  79.     Assign HELP:   MUI:Docs ADD
  80. EndIf
  81.  
  82. ; start arexx if not running
  83. CUCD:rexxc/rx "address command" >NIL:
  84. If WARN
  85.     CUCD:System/RexxMast >NIL:
  86. EndIf
  87.  
  88. ; Set assigns and paths for programs on this CD
  89. CUCD:rexxc/rx CUCD:C/MakeAssigns
  90.  
  91. ;Start NewIcons if not already running
  92. If $NoNewIcons NOT EQ TRUE
  93.     CUCD:C/isnirunning
  94.     If NOT WARN
  95.         Run <NIL: >NIL: CUCD:C/NewIcons
  96.         CUCD:C/DefIcons
  97.     EndIf
  98. EndIf
  99.  
  100. ;BEGIN ClassAct
  101. CUCD:C/CAPrefs >NIL:
  102. ;END ClassAct
  103.  
  104. ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  105. IF $CDBoot NOT EQ TRUE
  106.     Version >NIL: C:LoadWB 43
  107.     If WARN
  108.        C:LoadWB NEWPATH
  109.     Else
  110.         Version >NIL: C:LoadWB 60
  111.         If NOT WARN
  112.             C:LoadWB NEWPATH
  113.         EndIf
  114.     EndIf
  115. EndIf
  116.  
  117. ; Check that libraries on boot drive are up to date
  118. ;Execute CUCD:S/UpdateLibrary rexxdossupport.library 3 5
  119. ;Execute CUCD:S/UpdateLibrary rexxreqtools.library  37 95
  120. ;Execute CUCD:S/UpdateLibrary newicon.library 39 1
  121. ;Execute CUCD:S/UpdateLibrary cando.library 3 8
  122.  
  123. ; Give option for setting CD preferences
  124. If $CDBoot NOT EQ TRUE
  125.     Version >NIL: version 37
  126.     If NOT WARN
  127.         set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  128.         If $edit EQ 1
  129.             cd CUCD:S
  130.             :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  131.         Else
  132.             RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  133.         EndIf
  134.     Else
  135.         If NOT EXISTS ENV:IDer.prefs
  136.             Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  137.         EndIf
  138.     EndIf
  139. EndIf
  140.  
  141. SetEnv CDInit TRUE
  142.  
  143. LAB END
  144.  
  145.